feat: backend selection (Wayland, X11, Cocoa)

1 files changed, 44 insertions, 0 deletions

diff --git a/tests/meson.build b/tests/meson.build
new file mode 100644
index 0000000..a78ae65
--- /dev/null
+++ b/tests/meson.build
@@ -0,0 +1,44 @@
+test_exe = executable(
+    'yasl-test',
+    'test_lifecycle.c',
+    include_directories: inc,
+    link_with: yasl_lib.get_static_lib(),
+)
+
+add_test_setup('asan')
+add_test_setup('tsan')
+add_test_setup('msan')
+
+test('basic', test_exe)
+
+selection_test = executable(
+    'yasl-selection-test',
+    'common/test_selection.c',
+    dependencies: yasl_dep,
+)
+test('selection', selection_test)
+
+if get_option('integration_tests')
+    if has_cocoa
+        native_test = executable('yasl-native-test', 'cocoa/test_native.c',
+            dependencies: yasl_dep,
+        )
+        test('native', native_test, timeout: 20)
+    else
+        if not has_wayland or not has_x11
+            error('Linux integration tests require Wayland and X11.')
+        endif
+        backend_test = executable(
+            'yasl-backend-test',
+            'common/test_backends.c',
+            dependencies: yasl_dep,
+        )
+        python = find_program('python3')
+        weston = find_program('weston')
+        xwayland = find_program('Xwayland')
+        test('backends', python,
+            args: [files('helpers/run_backends.py'), weston, xwayland, backend_test],
+            timeout: 60,
+        )
+    endif
+endif